The MAX7219 module - LED matrix 8x8

Serial-Data Format (16 Bits)

Here's how addr data is organized:

• addr can only take hexadecimal values [00..0f]. These are the bits D8 to D11 marked ADDRESS in the box above.
• data follows addr

Les adresses $0d et $0e ne sont pas exploitées.

Here are the actions performed by the addresses addr:

• addr $00 without action
• addr $01..$08 row of LEDs to light, data $ 00 .. $ ff
• addr $09 decoding mode: $ 00 = no decoding; $ 01 = BCD decoding (do not use for 8x8 LED array
• addr $0a display intensity setting: $ 00 .. $ 0f, $ 00 being the minimum intensity, $ 0f being the maximum intensity;
• addr $0b limit range of rows to display: $ 00 .. $ 07; put $ 07 to handle all the LED array
• addr $0c disables the display: $ 00 .. $ 01; put $ 01 to make the LEDs visible.
• addr $0f tests the display. Allows you to check the status of all the LEDs. Values: $00 normal operations; $ 01 LED test mode.

Here are the words to manage the 8x8 LED matrix via the MAX7219 module.

The word max7219.send passes two bytes to the MAX7219 module:

: max7219.send ( c1 c2 -- ) 
    mSS1 slave.select 
    swap spi.csend spi.csend  
    mSS1 slave.deselect 
  ; 

The words disp.normal and disp.shutdown respectively allow to use the normal or disabled display mode:

: disp.normal   ( -- )  
    $0c $01 max7219.send ; 
: disp.shutdown ( -- )  
    $0c $00 max7219.send ; 

The words disp.test.on and disp.test.off allow you to activate or disable the test mode of the LEDs:

: disp.test.on  ( -- )  
    $0f $01 max7219.send ; 
: disp.test.off ( -- )  
    $0f $00 max7219.send ; 

The word disp.no.op has no action. It is used in the case of linked MAX7219 modules.

: disp.no.op      ( -- )     
    $00 $00  max7219.send ; 

The word disp.intensity is used to set the intensity of the LEDs in normal display. This setting affects all the LEDs of the 8x8 matrix.

: disp.intensity  ( c -- )   
    $0a swap max7219.send ; 

The word disp.decode is used to select the decoding mode of the MAX7219 module.

: disp.decode     ( c -- )   
    $09 swap max7219.send ; 

The word disp.scan.limit limits the action to only certain rows of LEDs.

: disp.scan.limit ( c -- )   
    $0b swap max7219.send ; 

And finally, the word disp.set.digit

: disp.set.digit  ( cbits cdigit -- )  
    swap max7219.send ; 

This word is used in the display test examples below.

Some display tests

The word disp-test-1 is used to test the display of the LEds of the matrix 8x8:

: disp-test-1 ( -- ) \ all LEDs on full, 232mA needed 
    spi.init 
    disp.test.on 
    begin key? until 
    disp.test.off 
    spi.close 
  ; 

Here is what gives the execution of the word disp-test-1:

Execution is interrupted by pressing a key on the keyboard.

The word disp-test-2 turns on the 4 left LEDs of the first row:

: disp-test-2 ( -- ) \ left 4 LEDs on first row, 42mA needed 
    spi.init 
    disp.normal 
    $03 disp.intensity 
    $00 disp.scan.limit 
    $f0 $01 disp.set.digit 
    begin key? until 
    disp.shutdown 
    spi.close 
  ; 

Here is what gives the execution of the word disp-test-2:

Execution is interrupted by pressing a key on the keyboard.

The word disp-test-3 displays a smiley character:

: disp-test-3 ( -- ) \ draw face, 18mA needed 
    spi.init 
    disp.normal 
    $01 disp.intensity 
    $07 disp.scan.limit 
    $00 disp.decode 
    %00000000 $01 disp.set.digit 
    %01100110 $02 disp.set.digit 
    %00000000 $03 disp.set.digit 
    %00011000 $04 disp.set.digit 
    %00011000 $05 disp.set.digit 
    %10000001 $06 disp.set.digit 
    %01000010 $07 disp.set.digit 
    %00111100 $08 disp.set.digit 
    begin key? until 
    disp.shutdown 
    spi.close 
  ; 

Here is what gives the execution of the word disp-test-3:

Execution is interrupted by pressing a key on the keyboard.